[WAT-AK336]기능 실험 키트 – 가변저항 값 FND에 표시

아두이노 보드 부저 울리기

[WAT-AK336]기능 실험 키트 예제 중 가변저항(potentiometer) 값(0~1023)을 FND 에 표시하는 예제입니다.

 

소스코드

 

최신 소스코드는 [파일]=>[예제]=>[WhiteAT UNO]=> [AK336] => [07_VR_FND]  에 있으며
라이브러리는 아두이노 개발환경(https://docs.whiteat.com/?page_id=5449)  을 참조하세요

/*
 [WAT-AK336]기능 실험 키트 예제 중
 가변저항 값을 FND ( 4-digit 7-segment) 에 표시하는 입니다.
 
 [WAT-AK336] 아두이노 기능 실험 키트: https://kit128.com/goods/view?no=336
 
 출처: https://docs.whiteat.com/?p=4565

*/

#define pinLatch 4
#define pinClock 7
#define pinData 8
 
#define pinVR A0 
unsigned int valVR = 0;
 
/* 0 부터 9 까지 숫자 모양 */
const byte SEGMENT_DATA[] = {0xC0,0xF9,0xA4,0xB0,0x99,0x92,0x82,0xF8,0X80,0X90,0xff};
/* 1 부터 4 까지의 자리 선택 */
const byte SEGMENT_SELECT[] = {0xF1,0xF2,0xF4,0xF8};
 
// 프로그램 초기화
void setup ()
{
 Serial.begin(115200);
 Serial.println("Arduino Examples - [WAT-AK336] potentiometer to FND");
 Serial.println(" https://docs.whiteat.com/?p=4565"); 
 
 /* 출력으로 설정 */
 pinMode(pinLatch,OUTPUT);
 pinMode(pinClock,OUTPUT);
 pinMode(pinData,OUTPUT);
}
 
// 계속 실행할 무한 루프
void loop()
{
 valVR = analogRead(pinVR);
 Serial.println(valVR); 
 /* 숫자 표시 */
 if(valVR>=1000) WriteNumberToSegment(0 , (valVR/1000));
 else WriteNumberToSegment(0 , 10);
 
 if(valVR >= 100) WriteNumberToSegment(1 , (valVR/100)%10);
 else WriteNumberToSegment(1 , 10);

 if(valVR>=10) WriteNumberToSegment(2 , (valVR/10)%10);
 else WriteNumberToSegment(2 , 10);
 
 WriteNumberToSegment(3 , valVR%10);
}
 
/* 각 자리에 숫자 표시 */
void WriteNumberToSegment(byte Segment, byte Value)
{
 // FND를 제어해 주는 HC595의 latch enable
 digitalWrite(pinLatch,LOW);
 
 // 숫자 모양을 설정
 shiftOut(pinData, pinClock, MSBFIRST, SEGMENT_DATA[Value]);
 
 // 자리수 설정
 shiftOut(pinData, pinClock, MSBFIRST, SEGMENT_SELECT[Segment] );
 
 // FND를 제어해 주는 HC595의 latch disable
 digitalWrite(pinLatch,HIGH);
}

결과 화면

가변저항 값(0~1023) 이 FND에 표시됩니다.